Distribución por origen de los visitantes en Cáceres

Mapa ofrecido por SIG Cáceres

Conjunto de datos que contiene la información catalogada por el ayuntamiento de Cáceres sobre el origen de los visitantes que visitan la ciudad.

URI del conjunto de datos: http://opendata.caceres.es/dataset/distribucion-por-origen-de-los-visitantes [HTML] [RDF].

Licencia de uso para los datos:

Este dataset se publica bajo la licencia Creative Commons Reconocimiento (CC by 3.0). Esta licencia permite que los datos sean copiados, distribuidos y divulgados libremente, tanto con fines comerciales o no comerciales siempre y cuando se reconozca la autoría de los datos: Ayuntamiento de Cáceres. Para más información revisar los términos de uso.

Información Técnica.

Punto SPARQL de acceso: http://opendata.caceres.es/sparql/

Grafo de almacenamiento: http://opendata.caceres.es/recurso/turismo/visitantes/Origen

Vocabulario utilizado: [schema] y [rdfs]

Esquema de URIs.

El esquema de dirección para todos los recursos se adapta a lo propuesto en la Norma Técnica de Interoperabilidad de Reutilización de Recursos de Información de la resolución de 19 de Febrero de 2013, de la Secretaría de Estado de Administraciones Públicas del Gobierno de España.

Todos los recursos comparten una URI Base en común : http://opendata.caceres.es/recurso/turismo/visitantes/Origen__{Fecha}__{ID}

Donde {Fecha} es la fecha en la que se contó el número de visitantes en formato "YYYY-MM-DD". Dependiendo de si son turistas nacionales o internacionales, el {ID} se utiliza el código postal o el nombre del país de origen de los visitantes respectivamente.

Utilización del Punto SPARQL.

Las consultas se realizan sobre el punto SPARQL: http://opendata.caceres.es/sparql/ y el grafo: http://opendata.caceres.es/recurso/turismo/visitantes/Origen

1) Mostrar el origen de los visitantes internacionales que visitaron la ciudad de Cáceres el último mes distribuido por días:
SELECT ?Pais ?Fecha ?Visitantes
WHERE {
 ?over a vis:Origen;
 vis:Volume ?Visitantes;
 vis:Country ?Pais;
 time:day ?Fecha
}
ORDER BY ASC(?Fecha) DESC(?Pais)
2) Mostrar el origen de los visitantes internacionales que visitaron la ciudad de Cáceres el último mes:
SELECT ?Pais ?Mes (SUM(?Volume) AS ?Visitantes)
WHERE {
 ?over a vis:Origen;
 vis:Volume ?Volume;
 vis:Country ?Pais;
 time:day ?Fecha .
 BIND((SUBSTR(STR(?Fecha),1,7)) AS ?Mes)
}
GROUP BY ?Pais ?Mes ORDER BY DESC(?Visitantes)
3) Mostrar el origen de los visitantes nacionales por código postal que visitaron la ciudad de Cáceres el último mes distribuido por días:
SELECT  ?Municipio ?Codigo_Postal ?Fecha ?Visitantes ?Provincia
WHERE {
 ?over a vis:Origen;
 vis:Volume ?Visitantes;
 vis:PostCode ?Codigo_Postal;
 vis:Township ?Municipio;
 vis:Province ?Provincia;
 time:day ?Fecha .
}
ORDER BY ASC(?Fecha) DESC(?Visitantes)
4) Mostrar el origen de los visitantes nacionales por código postal que visitaron la ciudad de Cáceres el último mes:
SELECT  ?Municipio ?Codigo_Postal ?Provincia ?Mes (SUM(?Volume) AS ?Visitantes)
WHERE {
 ?over a vis:Origen;
 vis:Volume ?Volume;
 vis:PostCode ?Codigo_Postal;
 vis:Township ?Municipio;
 vis:Province ?Provincia;
 time:day ?Fecha .
 BIND((SUBSTR(STR(?Fecha),1,7)) AS ?Mes)
}
GROUP BY ?Codigo_Postal ?Municipio ?Provincia ?Mes ORDER BY DESC(?Visitantes)
5) Mostrar el origen de los visitantes nacionales por provincia que visitaron la ciudad de Cáceres el último mes distribuido por días:
SELECT  ?Provincia ?Fecha (SUM(?Volume) AS ?Visitantes)
WHERE {
 ?over a vis:Origen;
 vis:Volume ?Volume;
 vis:Province ?Provincia;
 time:day ?Fecha .
}
GROUP BY ?Provincia ?Fecha ORDER BY ASC(?Fecha) DESC(?Visitantes)
6) Mostrar el origen de los visitantes nacionales por provincia que visitaron la ciudad de Cáceres el último mes:
SELECT  ?Provincia ?Mes (SUM(?Volume) AS ?Visitantes)
WHERE {
 ?over a vis:Origen;
 vis:Volume ?Volume;
 vis:Province ?Provincia;
 time:day ?Fecha .
 BIND((SUBSTR(STR(?Fecha),1,7)) AS ?Mes)
}
GROUP BY ?Provincia ?Mes ORDER BY DESC(?Visitantes)
7) Mostrar el origen de los visitantes completo que visitaron la ciudad de Cáceres el último mes:
SELECT  ?Municipio ?Codigo_Postal ?Provincia ?Mes ?Pais (SUM(?Volume) AS ?Visitantes)
WHERE {
 ?over a vis:Origen;
 vis:Volume ?Volume;
 time:day ?Fecha .
 OPTIONAL{?over vis:PostCode ?Codigo_Postal.}
 OPTIONAL{?over vis:Township ?Municipio.}
 OPTIONAL{?over vis:Province ?Provincia.}
 OPTIONAL{?over vis:Country ?Pais.}
 BIND((SUBSTR(STR(?Fecha),1,7)) AS ?Mes)
} 
GROUP BY ?Codigo_Postal ?Municipio ?Provincia ?Pais ?Mes ORDER BY DESC(?Visitantes)

Se puede encontrar más información sobre el lenguaje de consultas SPARQL en la página del W3C SPARQL.

Datos y Recursos

Información adicional

Campo Valor
Autor SIG de Cáceres
Mantenedor SIG de Cáceres
Última actualización 2020-10-16T10:58:35+0000
Creación 2019-10-28T17:39:55+0000
Frecuencia de actualización Mensual