Perfil del Contratante Cáceres

Mapa ofrecido por SIG Cáceres

Conjunto de datos que contiene la información relativa a los contratos públicos de las instituciones de Cáceres. Los órganos de contratación sobre los que se tiene información son los siguientes:

  • Ayuntamiento de Cáceres (AYTO).
  • Instituto Municipal de Juventud (IMJ).
  • Instituto Municipal de Deportes (IMD).
  • Universidad Popular (UP).
  • Instituto Municipal de Asuntos Sociales (IMAS).

URI del conjunto de datos: http://opendata.caceres.es/dataset/perfil-del-contratante-caceres [HTML] [RDF].

Licencia de uso para los datos:

Este dataset se publica bajo la licencia Creative Commons Reconocimiento (CC by 3.0). Esta licencia permite que los datos sean copiados, distribuidos y divulgados libremente, tanto con fines comerciales o no comerciales siempre y cuando se reconozca la autoría de los datos: Ayuntamiento de Cáceres. Para más información revisar los términos de uso.

Información Técnica.

Punto SPARQL de acceso: http://opendata.caceres.es/sparql/

Grafo de almacenamiento: http://opendata.caceres.es/recurso/sector-publico/perfil-contratante/

Vocabularios utilizados: OntoMunicipio, Public Procurement Ontology, Organization Ontology, Good Relations Ontology, dcterms, pc y schema

Esquema de URIs.

El esquema de dirección para todos los recursos se adapta a lo propuesto en la Norma Técnica de Interoperabilidad de Reutilización de Recursos de Información de la resolución de 19 de Febrero de 2013, de la Secretaría de Estado de Administraciones Públicas del Gobierno de España.

Todos los recursos comparten una URI Base en común : http://opendata.caceres.es/recurso/sector-publico/perfil-contratante/

Esta URI base sirve tanto para los contratos como para los órganos de contratación. La uri se desdobla de la siguiente manera:

Contratos:
http://opendata.caceres.es/recurso/sector-publico/perfil-contratante/Contrato/ + {Id_Contrato}-{nombre}

  • Id_Contrato es un identificador único.
  • nombre es el título del contrato.

Órganos de contratación:
http://opendata.caceres.es/recurso/sector-publico/perfil-contratante/Organizacion/ + {Id_Organización}-{nombre}

  • Id_Organización es un identificador único.
  • nombre es el nombre de la institución.

URIs de ejemplo:

1) Para Contrato Público:

URI identificadora del recurso: http://opendata.caceres.es/recurso/sector-publico/perfil-contratante/Contrato/227-servicio-de-prevencion-ajeno-de-riesgos-laborales-para-el-desarrollo-de-las-especialidades-de-medicina-del-trabajo-e-higiene

URI para el recurso en formato HTML: http://opendata.caceres.es/recurso/page/sector-publico/perfil-contratante/Contrato/227-servicio-de-prevencion-ajeno-de-riesgos-laborales-para-el-desarrollo-de-las-especialidades-de-medicina-del-trabajo-e-higiene

URI para el recurso en formato RDF: http://opendata.caceres.es/recurso/data/sector-publico/perfil-contratante/Contrato/227-servicio-de-prevencion-ajeno-de-riesgos-laborales-para-el-desarrollo-de-las-especialidades-de-medicina-del-trabajo-e-higiene

2) Para órgano de contratación:

URI identificadora del recurso: http://opendata.caceres.es/recurso/sector-publico/perfil-contratante/Organizacion/G10298743-imj

URI para el recurso en formato HTML: http://opendata.caceres.es/recurso/page/sector-publico/perfil-contratante/Organizacion/G10298743-imj

URI para el recurso en formato RDF: http://opendata.caceres.es/recurso/data/sector-publico/perfil-contratante/Organizacion/G10298743-imj

Propiedades Utilizadas.

Las propiedades que se están utilizando para describir los contratos públicos son las siguientes: Propiedades utilizadas en los contratos públicos

Las propiedades que se están utilizando para describir los órganos de contratación son las siguientes: Propiedades utilizadas en los órganos de contratación

Utilización del Punto SPARQL.

Las consultas se realizan sobre el punto SPARQL: http://opendata.caceres.es/sparql/ y el grafo: http://opendata.caceres.es/recurso/sector-publico/perfil-contratante/

1) Número de contratos públicos:
select count(?uri) as ?numContratos  where {
  ?uri a pproc:Contract.
}
2) Número de contratos por ejercicio y tipo de contrato:
select ?ejercicio ?type (count(?uri) as ?numContratos) where{ 
  ?uri a pproc:Contract. 
  ?uri pproc:contractProcedureSpecifications ?procedureSpecification. 
  ?procedureSpecification pproc:procedureType ?type. 
  ?uri om:ejercicio ?ejercicio.  
}group by ?ejercicio ?type order by ?ejercicio
3) Tipo de contratos y cantidades por años:
select ?ejercicio ?type (sum(?precioAdjudicacionConIVA) as ?totalAdjudicaciones) where{
  ?uri a pproc:Contract. 
  ?uri pproc:contractProcedureSpecifications ?procedureSpecification. 
  ?procedureSpecification pproc:procedureType ?type. 
  ?uri om:ejercicio ?ejercicio. 
  ?contractObject pproc:contractEconomicConditions ?economicContitions . 
  ?economicContitions pproc:budgetPrice ?priceVAT. 
  ?priceVAT gr:hasCurrencyValue ?precioLicitacionConIVA. 
  ?priceVAT gr:valueAddedTaxIncluded "1"^^xsd:boolean. 
  ?uri pc:tender ?tender. 
  ?tender pc:offeredPrice ?priceTenderVAT. 
  ?priceTenderVAT gr:hasCurrencyValue ?precioAdjudicacionConIVA. 
  ?priceTenderVAT gr:valueAddedTaxIncluded "1"^^xsd:boolean. 
}group by ?ejercicio ?type order by ?ejercicio
4) Cantidades totales por empresa de las adjudicaciones en el último año:
select ?adjudicatario (sum(?precioAdjudicacionConIVA) as ?totalAdjudicaciones) where{ 
  ?uri a pproc:Contract. 
  ?uri om:ejercicio "2016"^^xsd:decimal.
  ?uri dcterms:title ?nombreLicitacion. 
  ?uri pproc:contractObject ?contractObject. 
  ?contractObject pproc:contractEconomicConditions ?economicContitions . 
  ?economicContitions pproc:budgetPrice ?priceVAT. 
  ?priceVAT gr:hasCurrencyValue ?precioLicitacionConIVA. 
  ?priceVAT gr:valueAddedTaxIncluded "1"^^xsd:boolean. 
  ?uri pc:tender ?tender. 
  ?tender pc:supplier ?adjudicatario. 
  ?tender pc:offeredPrice ?priceTenderVAT. 
  ?priceTenderVAT gr:hasCurrencyValue ?precioAdjudicacionConIVA. 
  ?priceTenderVAT gr:valueAddedTaxIncluded "1"^^xsd:boolean. 
}group by ?adjudicatario order by desc (?totalAdjudicaciones)
5) Información detallada sobre todos los contratos públicos:
select  distinct ?uri  ?url ?ejercicio ?nombreContrato ?identificador  ?organoContratacion (group_concat(?tipoContrato;separator=" ") as ?tiposContrato) ?formaAdjudicacion ?estadoAdjudicacion ?adjudicatario ?fechaInicioLicitacion ?fechaLimiteLicitacion  ?importeSinIVA ?importeConIVA  ?fechaAdjudicacionProvisional ?fechaAdjudicacionDefinitiva ?importeAdjudicacionSinIVA ?importeAdjudicacionConIVA   (group_concat(?documento;separator="  ") as ?documentos) where {
  ?uri a pproc:Contract.
  ?uri om:ejercicio ?ejercicio.
  ?uri rdf:type ?tipoContrato.

  optional{?uri schema:url ?url.}.
  optional{?uri pc:contractingAuthority ?organoContratacion.}.
  ?uri dcterms:title ?nombreContrato.
  ?uri dcterms:identifier ?identificador.
  ?uri pproc:contractProcedureSpecifications ?specifications.
  ?specifications pproc:procedureType ?formaAdjudicacion.

  optional { ?specifications pproc:tenderDossierStartDate ?fechaInicioLicitacion } .
  optional { ?specifications pproc:tenderDeadline ?fechaLimiteLicitacion } .

  ?uri pproc:contractObject ?contractObject.

  optional{?contractObject pproc:contractEconomicConditions ?economicConditions.

  ?economicConditions pproc:budgetPrice ?priceSpecification.
  ?priceSpecification gr:valueAddedTaxIncluded "0"^^xsd:boolean.
  optional{?priceSpecification gr:hasCurrencyValue ?importeSinIVA.}.

  ?economicConditions pproc:budgetPrice ?priceSpecification2.
  ?priceSpecification2 gr:valueAddedTaxIncluded "1"^^xsd:boolean.
  optional{?priceSpecification2 gr:hasCurrencyValue ?importeConIVA.}.}.

  optional{?uri pproc:documentReference ?documento.}.

  ?uri pc:tender ?tender.

  ?tender pc:offeredPrice ?offeredPrice.
  ?tender pc:offeredPrice ?offeredPrice2.
  ?offeredPrice gr:valueAddedTaxIncluded "0"^^xsd:boolean.
  optional{?offeredPrice gr:hasCurrencyValue ?importeAdjudicacionSinIVA.}.
  ?offeredPrice2 gr:valueAddedTaxIncluded "1"^^xsd:boolean.
  optional{?offeredPrice2 gr:hasCurrencyValue ?importeAdjudicacionConIVA.}.

  optional {?tender pc:supplier ?adjudicatario.}.
  optional {?tender pproc:awardDate ?fechaAdjudicacionProvisional }.
  optional {?tender pproc:formalizedDate ?fechaAdjudicacionDefinitiva } .

  ?tender rdf:type ?estadoAdjudicacion.
  filter(!regex(?estadoAdjudicacion,"http://purl.org/procurement/public-contracts#Tender","i")).
 }

Se puede encontrar más información sobre el lenguaje de consultas SPARQL en la página del W3C SPARQL.

Datos y Recursos

Información adicional

Campo Valor
Autor SIG de Cáceres
Mantenedor SIG de Cáceres
Última actualización 2019-05-23T07:17:27+0000
Creación 2016-09-21T08:25:31+0000
Frecuencia de actualización Anual